Computers and Programming Experiences

Generate SSH2 (DSA) Key File on Windows PC/Laptop

1. Open PuttyGen
2. Change type of key to Generate to SSH-2 DSA.
3. Click Generate and move mouse in blank area until random key generated.
4. Under Key comment enter RaspberryPi
5. Under Key Passphase and Confirm Passphrase enter a new secure passphrase (password)
6. Go to Conversions->Export OpenSSH and export your private key with filename id_dsa.
7. Click Save private key button and save as a ppk file for later use.
8. Transfer newly generated SSH Private key to your Raspberry Pi (USB, Email, etc)  

1. Run the following code to create the SSH Directory on the Raspberry Pi :
   cd ~
mkdir .ssh
chmod 700 .ssh
2. Copy your SSH Private key you transferred to ~/.ssh/id_dsa
3. Run the following code to covert the SSH Private Key : 
   ssh-keygen -e -f ~/.ssh/id_dsa > ~/.ssh/id_dsa_com.pub
ssh-keygen -i -f ~/.ssh/id_dsa_com.pub > ~/.ssh/id_dsa.pub
mv ~/.ssh/id_dsa.pub ~/.ssh/authorized_keys
chmod 600 ~/.ssh/authorized_keys

1. Open SSH Config file :
   sudo nano /etc/ssh/sshd_config
2. Change Port 22 from standard to Port 2222 (or any other unused port for enhanced security)
3. Unhash and set PasswordAuthentication no (stops user/password entry)
4. Save Config File (CTRL+x, Press Y and enter on filename)
5. Restart SSH to accept changes :
   sudo service ssh restart 

1. Open Putty on Windows PC/Laptop.
2. Under Category expand ssh and click Auth.
3. Under Authentication Parameters click Browse under "Private key file for authentication".
4. Browse and select the private key file (ppk) you saved earlier.
5. Under Category expand ssh and click Session.
6. Under Host Name enter the IP Address of your Raspberry Pi.
7. Under Port enter 2222 or the port number you configured ealrier.
8. Under Saved Sessions enter  RaspberryPi
9. Click Save.
10. Click Open.
11. Login prompt should be displayed enter pi or you configured user name to access the Raspberry Pi.
12. If all successful you should then see Authenticating with public key and enter you secure passphrase.
13. Enter secure Passphrase.
14. You should now be connected securely to you Raspberry Pi.

Flash Particle Sparkler
Simple Particle Sparkler, the version above has the addition of a sparkler image to complete the bonfire night effect.

The Particle Sparkler can be seen on my sister site Flash Experiences it can be found here Particle Sparkler.

import com.Particle;

  Mouse.hide();

  this.objParticle = new Particle();

  addChild(this.objParticle);

package com
{
  // Import External Classes
  import flash.display.Bitmap;
  import flash.display.Sprite;
  import flash.events.Event;
  import flash.events.TimerEvent;
  import flash.filters.BlurFilter;
  import flash.geom.Point;
  import flash.utils.Timer;

  /**
   * Name        : Particle
   * Coded By       : Matt Wakeling
   * Date        : 22nd November 2011
   * Description : Particle Class for Particle Effect.
   *
   * @author Matt Wakeling
   */
  public class Particle extends Sprite
  {
    // Initialise Class Properties
    private var objParticleTimer:Timer;

    private const MAX_PARTICLES:int = 150;

    //Parictle Constuctor
    public function Particle()
    {
      super();
      InitialiseParticle();
    }

    // InitialiseMain Method
    private function InitialiseParticle():void
    {
       if (stage)
         this.InitialiseStage();
       else
         addEventListener(Event.ADDED_TO_STAGE, this.InitialiseStage);
    }

    // InitialiseStage Method
    private function InitialiseStage(e:Event = null):void
    {
       removeEventListener(Event.ADDED_TO_STAGE, this.InitialiseStage);

       this.objParticleTimer = new Timer(1000 / 30);
       this.objParticleTimer.addEventListener(TimerEvent.TIMER, this.ParticleEvent, false, 0, true);
       this.objParticleTimer.start();
    }

    // ParticleEvent Method
    public function ParticleEvent(PEEvent:TimerEvent):void
    {
      if (this.numChildren < MAX_PARTICLES)
      {
        var objPixel:Pixel = new Pixel();

        objPixel.addPixel(new Point(this.mouseX, this.mouseY), new Point(((Math.random() * 10) - (Math.random() * 10)), (Math.random() * -5)));

        addChild(objPixel);

        objPixel = undefined;
      }
    }
  }
}

package com
{
  import flash.display.Graphics;
  import flash.display.Sprite;
  import flash.events.Event;
  import flash.filters.BlurFilter;
  import flash.filters.GlowFilter;
  import flash.geom.Point;

  /**
  * Name        : Pixel
  * Coded By      : Matt Wakeling
  * Date           : 23rd November 2011
  * Description    : Pixel Class for the Particle Class.
  *
  * @author Matt Wakeling
  */
  public class Pixel extends Sprite
  {
    // Intialise Class Properties
    private var pntPixelVector:Point = new Point(0,0);
    private var pntTempVector:Point = new Point(0,0);

    private const MINIMUM_SCALE_PERCENT:int = 10;
    private const MAXIMUM_SCALE_PERCENT:int = 100;
    private const PIXELSIZE:int = 3;
    private const GRAVITY:Number = 1.5;
    private const FRICTION:Number = 0.85;


    // Pixel Constructor
    public function Pixel()
    {
      // Constructor Code
      super();
      this.InitialisePixel();
    }

    // Initialise Method
    private function InitialisePixel():void
    {
      // Initiailise Stage
      if (stage)
        this.InitialiseStage();
      else
        addEventListener(Event.ADDED_TO_STAGE, InitialiseStage);
    }

    // init Method
    private function InitialiseStage(e:Event = null):void
    {
      removeEventListener(Event.ADDED_TO_STAGE, InitialiseStage);

      addEventListener(Event.ENTER_FRAME, FrameEvent);
    }

    // addPixel Method
    public function addPixel(pntPosition:Point, pntVector:Point):void
    {
      // Draw Pixel
      this.graphics.clear();
      this.graphics.beginFill(0xFFFFFF);
      this.graphics.drawCircle(0, 0, this.PIXELSIZE);

      this.x = pntPosition.x;
      this.y = pntPosition.y;

      this.pntPixelVector = pntVector;
      this.pntTempVector = new Point(pntVector.x, pntVector.y);

      addEventListener(Event.ENTER_FRAME, FrameEvent);
    }

    // FrameEvent Method
    private function FrameEvent(FEEvent:Event):void
    {
      this.x += this.pntPixelVector.x;
      this.y += this.pntPixelVector.y;

      this.pntPixelVector.x *= this.FRICTION;
      this.pntPixelVector.y += this.GRAVITY;

      var numRandomScale:Number = ((Math.floor(Math.random() * (this.MAXIMUM_SCALE_PERCENT - this.MINIMUM_SCALE_PERCENT + 1)) + this.MINIMUM_SCALE_PERCENT)/100);
      this.scaleX = this.scaleY = numRandomScale;
      numRandomScale = undefined;

      this.filters = [new GlowFilter(0xFFD700, 1, 5, 5, 2, 1), new BlurFilter((this.pntPixelVector.x * 0.5), (this.pntPixelVector.y * 0.5), 1)];

      if (this.y > stage.stageHeight)
      {
        this.x = this.parent.mouseX; // MouseX point values are affected by Scale changes, so using parent values.
        this.y = this.parent.mouseY; // MouseY point values are affected by Scale changes, so using parent values.

        this.pntPixelVector.x = this.pntTempVector.x;
        this.pntPixelVector.y = this.pntTempVector.y;
      }
    }
  }
}

Flash Horizontal Starfield
Simple 4Kb Parallax Scrolling Starfield, the viewable version contains extra functionality to control the amount of Stars and Starfield Speed. On-screen diagnostics have been displayed as they may help influence any changes you decide to make.

The Starfield can be seen on my sister site Flash Experiences it can be found here Flash Horizontal Starfield.

import com.horizontalstarfield.Starfield;
 
var objStarfield:Starfield = new Starfield();
objStarfield.STAR_SPEED = 4;                  // By default this is currently set to 5.
 
addChild(this.objStarfield);

package com.horizontalstarfield
{
  import flash.events.*;
  import flash.display.*;
 
  /**
  * Name        : Starfield
  * Coded By    : Matt Wakeling
  * Date        : 20th November 2011
  * Description : Starfield Class for the main Starfield.
  *
  * @author Matt Wakeling
  */
  public class Starfield extends Sprite
  {
    // Intialise Class Properties
    private const START_STARS:int = 150;
    private const MINIMUM_ALPHA_PERCENT:int = 10;
    private const MAXIMUM_ALPHA_PERCENT:int = 100;
 
    public var STAR_SPEED:int = 5;
 
    // Starfield Constructor
    public function Starfield()
    {
      // Constructor Code
      super();
      this.InitialiseStarfield();
    }
 
    // InitialiseStarfield Method
    private function InitialiseStarfield():void
    {
      if (stage)
        this.InitialiseStage();
      else addEventListener(Event.ADDED_TO_STAGE, this.InitialiseStage);
    }
 
    // InitialiseStage Method
    private function InitialiseStage(e:Event = null):void
    {
      removeEventListener(Event.ADDED_TO_STAGE, this.InitialiseStage);
 
      var objStar:Star;
 
      var intLoopCounter:int = 1;
      while (intLoopCounter <= this.START_STARS)
      {
        objStar = new Star();
        objStar.x = (Math.random() * stage.stageWidth);
        objStar.y = (Math.random() * stage.stageHeight);
        objStar.alpha = ((Math.floor((Math.random() * ((this.MAXIMUM_ALPHA_PERCENT - this.MINIMUM_ALPHA_PERCENT) + 1))) + this.MINIMUM_ALPHA_PERCENT) / 100);
        objStar.STAR_SPEED = this.STAR_SPEED;
        addChild(objStar);
 
        objStar = undefined;
 
        intLoopCounter++;
      }
    }
  }
}
 

package com.horizontalstarfield
{
  import flash.display.Graphics;
  import flash.display.Sprite;
  import flash.events.Event;
 
  /**
  * Name        : Star
  * Coded By    : Matt Wakeling
  * Date        : 20th November 2011
  * Description : Star Class for the Starfield Class.
  *
  * @author Matt Wakeling
  */
  public class Star extends Sprite
  {
    // Intialise Class Properties
    private const MINIMUM_ALPHA_PERCENT:int = 10;
    private const MAXIMUM_ALPHA_PERCENT:int = 100;
 
    private var intStageWidth:int;
    private var intStageHeight:int;
 
    public var STAR_SPEED:int = 5;
 
    // Star Constructor
    public function Star()
    {
      // Constructor Code
      super();
      this.InitialiseStar();
    }
 
    // Initialise Method
    private function InitialiseStar():void
    {
      // Initiailise Stage
      if (stage) this.InitialiseStage();
      else addEventListener(Event.ADDED_TO_STAGE, InitialiseStage);
    }
 
    // InitialiseStage Method
    private function InitialiseStage(e:Event = null):void
    {
      removeEventListener(Event.ADDED_TO_STAGE, InitialiseStage);
 
      this.intStageWidth = stage.stageWidth;
      this.intStageHeight = stage.stageHeight;
 
      // Draw Star
      this.graphics.clear();
      this.graphics.beginFill(0xFFFFFF);
      this.graphics.drawCircle(0, 0, 1);
 
      addEventListener(Event.ENTER_FRAME, FrameEvent);
    }
 
 
    // FrameEvent Method
    private function FrameEvent(e:Event):void
    {
      this.x -= alpha * STAR_SPEED;
 
      if (this.x < 0)
      {
        this.x = this.intStageWidth;
        this.y = Math.random() * intStageHeight;
        alpha = ((Math.floor(Math.random() * (this.MAXIMUM_ALPHA_PERCENT - this.MINIMUM_ALPHA_PERCENT + 1)) + this.MINIMUM_ALPHA_PERCENT)/100);
      }
    }
  }
}